@echo off
rem Time-stamp: <2007/11/14, 10:21:40 (EST), maverick, pdf-1c.bat>
setlocal

rem settings
set _pdf_defoffset=4.25
set _pdf_tmpfile=_pdf-1cA_.pdf
set _pdf_tmpjobname=_pdf-1cB_
set _pdf_zoom=1.2
set _pdf_mooz=0.83

rem ensure the input exists
if [%1]==[] goto usage
if not exist %1 goto notfound

rem set default offset if needed
set _pdf_offset=%2
if "%_pdf_offset%"=="" set _pdf_offset=%_pdf_defoffset%

rem make a temp file to deal with spaces
if exist %_pdf_tmpfile% goto tempexists
if exist %_pdf_tmpjobname%.pdf goto tempexists
copy %1 %_pdf_tmpfile% > nul

rem set job name with no double quotes, assumes input ending with .pdf
set _pdf_jobname=%1
set _pdf_jobname=%_pdf_jobname:"=%
set _pdf_jobname=%_pdf_jobname:~0,-4%-1c

rem Go!
echo Generating [%_pdf_jobname%.pdf]...
rem 1. make a zoomed temp file
pdflatex -quiet -job-name="%_pdf_tmpjobname%" "\documentclass[twoside]{article}\usepackage{pdfpages}\begin{document}\includepdf[pages=-,doublepages,offset={%_pdf_offset%in 0in},scale=%_pdf_zoom%]{%_pdf_tmpfile%}\end{document}\batchmode" > nul
rem 2. shrink it back for the real output
pdflatex -quiet -job-name="%_pdf_jobname%" "\documentclass[twoside]{article}\usepackage{pdfpages}\begin{document}\includepdf[pages=-,scale=%_pdf_mooz%]{%_pdf_tmpjobname%.pdf}\end{document}\batchmode" > nul
if exist "%_pdf_jobname%.pdf" goto cleanup
echo Trouble generating [%_pdf_jobname%.pdf]. See [%_pdf_jobname%.log].
goto end

:cleanup
echo Done.
del "%_pdf_tmpfile%"
del "%_pdf_tmpjobname%.log"
del "%_pdf_tmpjobname%.aux"
del "%_pdf_tmpjobname%.pdf"
del "%_pdf_jobname%.log"
del "%_pdf_jobname%.aux"
goto end

:tempexists
echo Temp file [%_pdf_tmpfile%] or [%_pdf_tmpjobname%.pdf] exists. Please delete it first.
goto end

:notfound
echo File [%1] not found.
rem fall through

:usage
echo Usage: %0 foo.pdf [offset]  (offset defaults to %_pdf_defoffset%)
goto end

:end